echo off
rem With America OnLine, changing above to ECHO ON will prevent bad command or
rem file name error that occur after downloading this file.
rem Modified 9-15-96 to auto-run CVT9X99.
rem Created Apr 24, 1996 - Use MAKEDNLD to creat Zipped VSM file for download.
echo VSMDNLD used to UnZip VSM files in temporary directory, then move them to
echo their permanent directories.
echo UnZipped VSM files must be in current directory on same drive as \HVSM.
if %1X==X goto :NoParm
if not exist %1.zip goto :NoZip
if exist *.dat goto :BadDir
if exist *.bat goto :BadDir
if exist *.exe goto :BadDir
if not exist \hvsm\vsm.exe goto :BadDrive
if not exist \batch\vsm.bat goto :BadDrive
if %2X==X goto :NoParm2
rem 8-9-96 added supported for data encryption
pkunzip %1 -s%2
goto :ChkZip
:NoParm2
pkunzip %1
:ChkZip
if errorlevel 1 goto :ZipErr
echo Moving *.BAT files to \BATCH directory ...
if exist *.bat move *.bat \batch
echo Moving *.EXE and *.OVR executables to \HVSM directory ...
if exist *.exe move *.exe \hvsm
if exist *.ovr move *.ovr \hvsm
echo Moving VSM Manual to \HVSM directory ...
if exist vsm.txt move vsm.txt \hvsm
rem Moving any Implemented Feature List (e.g. FEAT98T.TXT) ...
if exist *.txt move *.txt \hvsm
echo ........................................
echo Installation of VSM download files has completed.
echo .
cd \hvsm
if exist cities.dat goto :CvtDone
echo Need to run CVT9X99 conversion ...
cvt9x99
if exist cvt9x99.exe del cvt9x99.exe
:CvtDone
cd \
echo User should delete %1.ZIP download file that is no longer needed.
if not exist \batch\getvsm.bat goto :Done
echo **** Warning ****** This appears to be a VSM network site.
echo Be sure your current directory is on the shared network drive; if not,
echo then repeat VSMDNLD with ZIP file on shared network drive.
echo The Server and each Workstation should run GETVSM after VSMDNLD finishes.
goto :Done
:BadDrive
echo ***** Error **********
echo Must be on wrong drive since existing \HVSM\VSM.EXE or \BATCH\VSM.BAT files
echo cound not be found. Note that VSMDNLD cannot be used for a first time
echo installation.
goto :Done
:ZipErr
echo ***** Error **********
echo Unexpected error in %1.ZIP file - may need to redownload file.
echo .
echo If "bad table" error produced by PKUNZIP, then you probably have an older
echo version of PKUNZIP.EXE that should be deleted - use DOS command:
echo    ff pkunzip.exe
echo to find all copies of PKUNZIP.EXE, then delete the old ones.
goto :Done
:NoParm
echo ***** Error **********
echo Must supply name of VSM Zip file as 1st command line parameter and
echo optional password as 2nd command line parameter (if you don't know the
echo password, then contact SMS).
echo For example, if VSM98T.ZIP was downloaded to C:\TMP directory, then enter:
echo   cd \tmp
echo   vsmdnld vsm98t pswd
goto :Done
:BadDir
echo ***** Error **********
echo In a directory that contains VSM data or needed program files.
echo Move %1.ZIP to an empty temporary directory (like C:\TMP), then repeat
echo the "VSMDNLD %1" command.
goto :Done
:NoZip
echo ***** Error **********
echo Could not find %1.ZIP file in current directory.
echo If the downloaded VSM Zip file was VSM98T.ZIP, then insure the file is in
echo the current directory (e.g. C:\TMP), then enter the command:
echo   vsmdnld vsm98t
goto :Done
rem ***********************
:Done
echo .
rem